Excel日期时间函数查询（超实用的16种使用方法）

WPS表格Excel全套课程:特色功能+函数+透视表+图表

输入自动更新的当前日期输入自动更新的当前日期和时间输入自动更新的当前时间计算今天对应的年份计算今天对应的月份计算今天对应的天数计算本月最后一天的日期计算本月有多少天计算今天是星期几（数字）计算今天是星期几（中文）计算今天是星期几（英文）计算今天是周几计算当前日期在本年度中的第几周计算当前日期在本年度中的第几季度输入自动更新的中文小写日期输入自动更新的中文大写日期

Excel日期时间函数查询

在职场工作中，对于日期和时间在Excel中的应用非常广泛的，如果能够熟练的掌握其应用技巧，对于提高统计效率是有很大帮助的。今天Excel办公小课堂就对于日期和时间函数就综合盘点一下，一共整理了16种经典案例，非常全面，建议先收藏，不然到时候需要就找不到了哦~

函数：

TODAY函数：表示返回当前电脑系统显示的日期

公式：

=TODAY()

示例：

说明：

TODAY是一个没有参数的函数，返回当前电脑系统中显示的日期，且跟系统同步更新。格式类型默认yyyy/m/d，若需要修改指定日期格式，可在【设置单元格格式】修改格式类型，如：yyyy-mm-dd（y表示年；m表示月；d表示日）

函数：

NOW函数：表示返回当前电脑系统显示的日期和时间

公式：

=NOW()

示例：

说明：

NOW是一个没有参数的函数，返回当前电脑系统中显示的日期和时间，且跟系统同步更新。格式类型默认yyyy/m/d h:mm，若需要修改指定日期格式，可在【设置单元格格式】修改格式类型，如：yyyy-mm-dd hh:mm:ss（y表示年；m表示月；d表示日；h表示小时；m表示分钟；s表示秒）

函数：

TODAY函数：表示返回当前电脑系统显示的日期

NOW函数：表示返回当前电脑系统显示的日期和时间

公式：

=NOW()-TODAY()

示例：

说明：

NOW函数，返回当前电脑系统中显示的日期和时间，TODAY返回当前电脑系统中显示的日期，通过NOW()-TODAY()相减则返回当前的时间，且所显示的时间与电脑系统同步更新

函数：

TODAY函数：表示返回当前电脑系统显示的日期

YEAR函数：表示返回指定日期的年份

公式：

=YEAR(TODAY())&"年"

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过YEAR函数对当前的日期计算得出当前（今天）对应的年份，默认显示的是数字2023，若需要加上“年”单位，在公式的最后通过连接字符连接上“年”，也就是&"年"（年是文本，在运算时对于文本字符需要用英文的双引号双引起来

函数：

TODAY函数：表示返回当前电脑系统显示的日期

MONTH函数：表示返回指定日期的月份

公式：

=MONTH(TODAY())&"月"

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过MONTH函数对当前的日期计算得出当前（今天）对应的月份，默认显示的是数字5，若需要加上“月”单位，在公式的最后通过连接字符连接上“月”，也就是&"月"（月是文本，在运算时对于文本字符需要用英文的双引号双引起来

函数：

TODAY函数：表示返回当前电脑系统显示的日期

DAY函数：表示返回指定日期的天数

公式：

=DAY(TODAY())&"号"

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过DAY函数对当前的日期计算得出当前（今天）对应的天数，默认显示的是数字9，若需要加上“号”单位，在公式的最后通过连接字符连接上“号”，也就是&"号"（号是文本，在运算时对于文本字符需要用英文的双引号双引起来

函数：

TODAY函数：表示返回当前电脑系统显示的日期

EOMONTH函数：表示指定月数之前或之后的月份的最后一天

公式：

=EOMONTH(TODAY(),0)

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过EOMONTH函数根据当前的日期，返回当前日期的最后一天日期。EOMONTH函数第二个参数0表示的是当月，若返回前一个月最后一天的日期EOMONTH第二参数就为-1；若返回后一个月最后一天的日期EOMONTH第二参数就为1。最后根据需要修改日期格式类型，如当前的格式类型是yyyy-mm-dd类型

函数：

TODAY函数：表示返回当前电脑系统显示的日期

EOMONTH函数：表示指定月数之前或之后的月份的最后一天

DAY函数：表示返回指定日期的天数

公式：

=DAY(EOMONTH(TODAY(),0))&"天"

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过EOMONTH函数根据指定的日期返回当前日期的最后一天的日期，其中EOMONTH函数第二参数“0”表示的是返回本月日期，若“-1”表示前一个月，若为“1”表示后一个月。最后通过DAY函数对当前的日期计算得出当前（今天）对应的天数，默认显示的是数字31，若需要加上“天”单位，在公式的最后通过连接字符连接上“天”，也就是&"天"（天是文本，在运算时对于文本字符需要用英文的双引号双引起来

函数：

TODAY函数：表示返回当前电脑系统显示的日期

WEEKDAY函数：表示返回指定日期是星期几

公式：

="星期"&WEEKDAY(TODAY(),2)

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过WEEKDAY函数返回当前日期的星期数。WEEKDAY函数第二参数2表示的是一周的第1天从星期一开始，返回值从数字 1（星期一）到 7（星期日），也就是我们国内标准星期顺序形式。最后公式得到结果是一个数字，为了让结果更为标准，在前面通过“星期”连接上函数公式，也就是得到星期几的效果

函数：

TODAY函数：返回当前电脑系统显示的日期

TEXT函数：将数值转换为指定数字格式表示的文本

公式：

=TEXT(TODAY(),"aaaa")

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过TEXT函数将当前日期转换为星期几的格式。TEXT函数第二参数“aaaa”表示的是返回指定日期（中文）星期几效果，若TEXT函数第二参数是“aaa”（三个字母a）可返回中文数值

函数：

TODAY函数：返回当前电脑系统显示的日期

TEXT函数：将数值转换为指定数字格式表示的文本

公式：

=TEXT(TODAY(),"dddd")

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过TEXT函数将当前日期转换为星期几的格式。TEXT函数第二参数“dddd”表示的是返回指定日期（英文）星期几效果，若TEXT函数第二参数是“ddd”（三个字母d）可返回（英文）星期几简写效果

函数：

TODAY函数：返回当前电脑系统显示的日期

TEXT函数：将数值转换为指定数字格式表示的文本

公式：

=TEXT(TODAY(),"周aaa")

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过TEXT函数将当前日期转换为星期几的格式。TEXT函数第二参数“周aaa”表示的是返回指定日期周几效果，当TEXT函数第二参数直接是“aaa”（三个字母a）可返回中文数字，前面加上文字“周”则可将日期格式改变成周几效果

函数：

TODAY函数：返回当前电脑系统显示的日期

WEEKNUM函数：返回一个数字，该数字代表一年中的第几周

公式：

=WEEKNUM(TODAY(),2)

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过WEEKNUM函数返回当前日期在本年中的第几周，其中WEEKNUM函数第二参数为“2”表示的星期从星期一开始（星期内的天数从1到7记数）

函数：

TODAY函数：返回当前电脑系统显示的日期

MONTH函数：返回指定日期的月份

LEN函数：返回文本字符串中的字符个数

TEXT函数：将数值转换为指定数字格式表示的文本

公式：

=TEXT(LEN(2^MONTH(TODAY())),"第0季度")

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过MONTH函数返回当前日期的月份值。公式中2^MONTH(TODAY())表示的是2的N次方，N根据MONTH(TODAY())返回月份值。最后通过LEN函数计算字符个数，例如2^5=32，通过LEN函数计算字符个数为2，从而得到当前季度是2。为了直观显示第几季度的效果，用TEXT函数进行转换指定数值格式，TEXT函数第二参数“第0季度”表示的是根据LEN(2^MONTH(TODAY()))计算得到的结果转换成第几季度的效果。当然也可以不用TEXT函数，直接用连接字符&公式为="第"&LEN(2^MONTH(TODAY()))&"季度"

函数：

TODAY函数：返回当前电脑系统显示的日期

TEXT函数：将数值转换为指定数字格式表示的文本

公式：

=TEXT(TODAY(),"[dbnum1]e年m月d日")

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过TEXT函数转换成中文小写日期格式类型。TEXT函数第二参数中[dbnum1]表示的是将单元格的数值格式设置为中文小写数字；e年m月d日表示的是显示年月日的效果，其中e年表示四位数年份数值

函数：

TODAY函数：返回当前电脑系统显示的日期

TEXT函数：将数值转换为指定数字格式表示的文本

公式：

=TEXT(TODAY(),"[dbnum2]e年m月d日")

示例：

说明：

因TODAY返回当前电脑系统中显示的日期，然后通过TEXT函数转换成中文大写日期格式类型。TEXT函数第二参数中[dbnum2]表示的是将单元格的数值格式设置为中文大写数字；e年m月d日表示的是显示年月日的效果，其中e年表示四位数年份数值

作者：Excel办公小课堂

今天分享的内容，建议收藏起来以备不时之需！

关注Excel办公小课堂

解锁办公技能，告别无效加班

看完点赞，月入过万~